10.4 Blade 배열 프로그램 코드

Blade Distribution Program Code

 

"본 프로그램 코드는 QuickBasic으로 작성된 것입니다."

 

DEFDBL A-H, O-Z

DEFINT I-N

DIM istn(500), ibld(500), ifree(1000), wm(500), sm(500)

DIM tm(500), sn(500), cs(500), theta(500), cjf(500), cg(500)

DIM wt(500), ifirst(500), bname(500) AS STRING * 12

DIM mline AS STRING, wfile AS STRING, title AS STRING, btitle AS STRING

DIM undrln AS STRING, dwgno AS STRING, verd AS STRING, lline AS STRING

DIM bignam AS STRING * 16, smlnam AS STRING * 16, name1 AS STRING * 16

DIM c1 AS STRING * 1, optp AS STRING * 1, optw AS STRING * 1

DIM worm AS STRING * 1

 

'istn(i) CURRENT STATION CONTAINING BLADE i (-ve if stn. is fixed)

'ibld(i) NUMBER OF BLADE CURRENTLY IN STATION i

'ifree(i) STATION NUMBER OF iTH FREE STATION

 

verd = "94.07.02"

undrln = "--------------"

degrad = ATN(1#) / 45#

raddeg = 1# / degrad

 

'GIVE NAME OF WEIGHT FILE AMD CHOOSE OPTION

PRINT "Give name of weight file?"

INPUT " File name; ", wfile

IF wfile <> " " THEN

PRINT "Do you want to sort blades to get balance in tolerance?"

PRINT " or to calculate lengths of existing arrangement?"

INPUT "Y or N;", ans$

IF UCASE$(ans$) = "Y" THEN

optw = "Y"

PRINT "Do you want to balance on weight?"

PRINT " or balance on moment?"

INPUT "Y or N;", r$

IF UCASE$(r$) = "Y" THEN

worm = "W"

ELSE

worm = "M"

END IF

ELSE

optw = "N"

worm = "M"

END IF

ELSE

wfile = "x"

optw = "N"

worm = "M"

END IF

IF (optw = "N") THEN

iswap = 0

ELSE

iswap = 1

END IF

'INITIALIZE EVERY IDENTIFIER TO BLANK & INITIAL STATION TO 0

INPUT "Blade drawing no. :"; dwgno

FOR i = 1 TO 500

istn(i) = 0

ibld(i) = 0

ifree(i) = 0

bname(i) = " "

NEXT i

totom = 0#

smlbld = 59.6#

bigbld = 62.811#

'INPUT NUMBER OF BLADE

INPUT " NO. of BLADE;", nblade

IF nblade < 1 OR nblade > 500 THEN

PRINT " Error- "; nbp; " is an illegal number of blade"

END IF

 

'INPUT BALANCE DATA

INPUT "Identification of input tbn stage? "; btitle

LPRINT "'KIM KAY YOUN' Moment Balancing Program-Version "; verd

LPRINT

LPRINT btitle

LPRINT undrln

LPRINT

LPRINT "Weight/Moment file : "; wfile

LPRINT ; "Blade Drawing No. : "; dwgno

wub = 6!: 'MAX. ACCEPTABLE UNBALANCE WT. AT BLADE C.G.

distol = .5: minmax = .01: minset = wub - minmax: maxset = wub + minmax

LPRINT "Max. acceptable unbalanced wt at blade C.G.:"; wub * 1000; " Gr "

LPRINT "Distribution tolerance ratio :"; distol; " No of blade ;"; nblade

LPRINT "Lower wt limit :"; smlbld; "KG"; " Upper wt limit :"; bigbld; "KG"

LPRINT

 

'IF NOT DOING A MOMENT OR WEIGHT BALANCE CHANGE wub TO SOMETHING VERY

'BIG & DISTOL TO 0

IF (optw = "N") THEN

wub = 1000000#

distol = 0#

END IF

IF (distol > 1#) THEN

LPRINT "Error-illegal distribution tolerance "; distol; "cannot exceed 1"

END IF

'kerr = 0 AS LONG AS DATA IS OK. GETS SET TO 1 IF AN ERROR IS FOUND

'nl = NO. OF MOVABLE BLADES

'nf = NO. OF FIXED-POSITION BLADES

'nt = TOTAL NO. OF BLADES

'kount COUNTS NUMBER OF LINES PRINTED ON CURRENT PAGE

kount = 10

bigwt = -1D+70

smlwt = -bigwt

IF (bigbld < .0000000001#) THEN bigbld = 1000#

FOR i = 1 TO nblade

bname(i) = " "

NEXT i

'READ ONE BLADE EACH TIME ROUND THIS LOOP

IF (wfile <> "x") THEN

ifirl = 0

ifirs = 0

FOR i = 1 TO nblade

'PUT OUT PAGE HEADING BEFORE FIRST BLADE OR START NEW PAGE & PUT OUT

'PAGE HEADING ON IT

IF (i <> 1) THEN

IF (kount <> 50) GOTO kcount

LPRINT CHR$(12)

END IF

LPRINT "INIT.STN IDENTIFIER WT(KG) JIGM(MM) MOMENT(KG-M)"

IF (i <> 1) THEN kount = 0

kcount:

kount = kount + 1

'READ IDENTIFIER

READ name1

IF (LEFT$(name1, 1) <> "-") THEN name1 = " " + name1

nn = LEN(name1)

FOR ii = 2 TO nn

IF (MID$(name1, ii, 1) < "0" OR MID$(name1, ii, 1) > "9") THEN GOTO figure

NEXT ii

ii = 13: 'THE END OF CHARACTER

figure:

IF (ii = 2) THEN

jstn = i

ELSE

jstn = VAL(LEFT$(name1, ii - 1))

END IF

'IF IDENTIFIER STARTS WITH - THE BLADE IS FIXED

'IF NOT, PUT A SPACE IN FRONT SO MINUS SIGN STANDS OUT IN O/P

IF (LEFT$(name1, 1) <> "-" AND jstn < 0) THEN

name1 = "-" + name1

END IF

IF (LEFT$(name1, 1) <> "-" AND LEFT$(name1, 1) <> " ") THEN

name1 = " " + name1

END IF

bname(i) = name1

IF (LEFT$(bname(i), 1) = "-") THEN

istn(i) = -ABS(jstn)

ELSE

istn(i) = jstn

END IF

jj = i

kstn = istn(i)

'CHECK THAT THIS STATION HASN'T BEEN FILLED ALREADY

FOR ii = 1 TO nblade

IF (ii <> i AND ABS(istn(ii)) = ABS(jstn)) THEN

LPRINT " ERROR-MORE THAN 1 BLADE IN STATION "; jstn; "IN WEIGHT FILE"

END IF

NEXT ii

 

'READ TOTAL WEIGHT(wt) & MOMENT(sm)OF EACH BLADE & TOTAL WEIGHT

'swt) & MOMENT(ssm)OF ROW

 

 

READ wt(jj), sm(jj), cjf(jj)

swt = swt + wt(jj)

ssm = ssm + sm(jj)

sjf = sjf + cjf(jj)

 

'SET INITIAL POSITION

IF (wt(jj) > bigwt) THEN

bigwt = wt(jj)

ibig = jj

bignam = bname(jj)

END IF

IF (wt(jj) < smlwt) THEN

smlwt = wt(jj)

isml = jj

smlnam = bname(jj)

END IF

c1 = " "

IF (wt(jj) > bigbld) THEN c1 = "H"

IF (wt(jj) < smlbld) THEN c1 = "L"

LPRINT USING "###"; kstn; : LPRINT SPC(8);

LPRINT USING "&"; name1; : LPRINT SPC(1);

LPRINT USING "##.###"; wt(jj); : LPRINT SPC(4);

LPRINT USING "###.##"; cjf(jj); : LPRINT SPC(6);

LPRINT USING "##.####"; sm(jj); : LPRINT SPC(1);

LPRINT USING "!"; c1

NEXT i

END IF

'END OF DATA INPUT LOOP

IF (bigbld < 9.99D+20) THEN

LPRINT " L=blade wt. below lower limit "

LPRINT " H=blade wt. above upper limit "

END IF

LPRINT CHR$(12)

'SET UP REFERENCES TO FREE STATIONS

nfree = 0

avwt = swt / nblade

hml = bigwt - smlwt

avjf = sjf / nblade

FOR i = 1 TO nblade

IF (istn(i) = 0) THEN nberr = 1

IF (istn(i) > 0) THEN

nfree = nfree + 1

ifree(nfree) = istn(i)

END IF

NEXT i

 

'MOMENT(SCHENCK ;sm) CONVERSION TO ACTUAL ROTOR MOMENT(tm)

'NB; swm INCLUDES UNDERSTRAPS, totmom DOES NOT

'IF DOING A MOMENT BALANCE PUT tm INTO wm ELSE PUT wt IN

'PUT SPARE COPY OF MOMENT INTO sn FOR USE IN CALCULATING DISTRIBUTION

'LIMITS

FOR i = 1 TO nblade

fcg = sm(i) / wt(i) - .4302 - avjf / 1000

cg(i) = 1.143 + fcg

tm(i) = cg(i) * wt(i)

totmom = totmom + tm(i)

swm = swm + tm(i)

avmom = swm / nblade

IF (worm = "M") THEN

wm(i) = tm(i)

ELSE

wm(i) = wt(i)

END IF

sn(i) = wm(i)

NEXT i

 

'RESULTANT LEVER ARM(TOTAL MOMENT/TOTAL MASS)

w1 = swt

IF (ABS(w1) < .000001#) THEN

swm = 0#

ELSE

swm = swm / w1

END IF

'BALANCE TOLERANCE SQUARED

IF (worm = "M") THEN

tol = (wub * swm) ^ 2 + .0000000001#

ELSE

tol = wub ^ 2 + .000000001#

END IF

'PRODUCE A LIST OF BLADES IN ASCENDING WEIGHT ORDER(FOR BAD

'DISTRIBUTION FUNCTION diss)

FOR i = 2 TO nblade

FOR j = 2 TO nblade

IF (sn(j) > sn(j - 1)) THEN GOTO ascend

SWAP sn(j), sn(j - 1)

ascend:

NEXT j

NEXT i

'PRODUCE A LIST OF BLADES IN ORDER: LIGHTEST, HEAVIEST, 2ND LIGHTEST,

'2ND HEAVIEST...ETC. (FOR GOOD DISTRIBUTION FUNCTION disb)

j = nblade / 2

k = -1

'FIRST SORT THEM IN PAIRS

'PUT SORTED ARRAY IN CS

FOR i = 1 TO j

k = k + 2

cs(k) = sn(i)

cs(k + 1) = sn(nblade - i + 1)

NEXT i

'IF nblade IS ODD, PUT THE REMAINING 1 ON THE END OF THE LIST

IF (j + j <> nblade) THEN cs(nblade) = sn(j + 1)

'WORK OUT DISTRIBUTION FUNCTIONS

'disb=BEST POSSIBLE

'diss=WORST POSSIBLE

'dist=SMALLEST VALUE WHICH WILL BE IN TOLERANCE

diss = (sn(nblade) - sn(1)) ^ 2

disb = (cs(nblade) - cs(1)) ^ 2

FOR i = 2 TO nblade

diss = (sn(i) - sn(i - 1)) ^ 2 + diss

disb = (cs(i) - cs(i - 1)) ^ 2 + disb

NEXT i

diss = .5# * diss

disb = .5# * disb

dist = diss + distol * (disb - diss) - .000001#

'WORK OUT ANGULAR POSITION OF EACH STATION ASSUMING EQUAL SPACING

'STATION nblade+1 IS SAME AS STATION 1(SO 1ST & LAST DON'T

'HAVE TO BE TREATED AS SPECIAL CASES)

'CALCULATE SINE & COSINE OF EACH

theta(1) = 0#

theta(2) = 360 / nblade

FOR i = 3 TO nblade

theta(i) = (i - 1) * theta(2)

NEXT i

FOR i = 1 TO nblade

sn(i) = SIN(degrad * theta(i))

cs(i) = COS(degrad * theta(i))

NEXT i

'WORK OUT WHICHBLADE IS IN EACH STATION

FOR i = 1 TO nblade

FOR jj = 1 TO nblade

IF (ABS(istn(jj)) = i) THEN ibld(i) = jj

NEXT jj

NEXT i

'FIX FIRST BLADE IF NONE ARE FIXED

IF (nfree = nblade) THEN

istn(ibld(1)) = -istn(ibld(1))

nfree = nfree - 1

FOR i = 1 TO nfree

ifree(i) = ifree(i + 1)

NEXT i

END IF

'DUPLICATE FREE STATION NUMBERS A SECOND TIME ROUND

FOR i = 1 TO nfree

ifree(i + nfree) = ifree(i)

NEXT i

'START OF SWAPPING CALCULATION

'WORK OUT NET UNBALANCE(UBNET), DISTRIBUTION(DFUN)

'FIRST PASS(ipass=1) - GET PACKET LENGTH INTO TOLERANCE

'SECOND PASS(ipass=2) - GET BALANCE INTO TOLERANCE BUT DON'T LET

' PACKET LENGTH GET OUT

'THIRD PASS (ipass=3) - GET DISTRIBUTION INTO TOLERANCE BUT DON'T

' LET PACKET LENGTHS & BALANCE GET OUT

ipass = 1

l1 = 1

xmu = 0#

ymu = 0#

'WORK OUT CURRENT BALANCE & DISTRIBUTION

result:

xm = xmu

ym = ymu

dfun = 0#

FOR is1 = 1 TO nblade

ib = ibld(is1)

is2 = is1 + 1

IF (is2 > nblade) THEN is2 = 1

ib1 = ibld(is2)

xm = xm + wm(ib) * sn(is1)

ym = ym + wm(ib) * cs(is1)

dfun = dfun + .5# * (wm(ib1) - wm(ib)) ^ 2

NEXT is1

ubnet = xm ^ 2 + ym ^ 2

IF (ABS(xm) < .0000000001# AND ABS(ym) < .0000000001#) THEN

ang = 0#

ELSEIF (xm > 0# AND ym = 0#) THEN

ang = 90#

ELSEIF (xm < 0# AND ym = 0#) THEN

ang = 270#

ELSEIF (xm > 0# AND ym > 0#) THEN

ang = ATN(xm / ym) * raddeg

ELSEIF (xm < 0# AND ym > 0#) THEN

ang = ATN(xm / ym) * raddeg + 360#

ELSE

IF (ym < 0#) THEN

ang = ATN(xm / ym) * raddeg + 180#

END IF

END IF

 

'IF THE TOLERANCE FOR THIS PASS IS SATISFIED GO TO NEXT PASS

'(OR EXIT AFTER 3RD PASS)

 

IF (ipass = 1) THEN

IF (ubnet > minset ^ 2 AND ubnet < maxset ^ 2) THEN

ipass = 2

GOTO result

END IF

 

ELSEIF (ipass = 2) THEN

IF (ang > 239 AND ang < 241) THEN

ipass = 3

GOTO result

END IF

ELSE

IF (dfun >= dist) GOTO resultout

END IF

'OUTER LOOP - COMPARE EACH BLADE WITH THE ONE L (L) STATIONS IN FRONT

OUTER:

FOR l = l1 TO nfree / 2

'GO ROUND THE WHOLE BLADE ROW

'IF WE DON'T DO A SWAP, THEN INCREMENT L AND TRY AGAIN

'IF WE DO SET L BACK TO 1 AND START AGAIN, UNLESS IT'S ALREADY 1, WHEN

'WE CONTINUE

FOR k = 1 TO nfree

is1 = ifree(k)

js = ifree(k + l)

ib = ibld(is1)

jb = ibld(js)

dw = wm(ib) - wm(jb)

dx = xm + dw * (sn(js) - sn(is1))

dy = ym + dw * (cs(js) - cs(is1))

IF (ABS(js - is1) = 1) THEN

 

IF (js > is1) THEN

jsm2 = js - 2

IF (jsm2 < 1) THEN jsm2 = jsm2 + nblade

jsp = js + 1

IF (jsp > nblade) THEN jsp = 1

dd = -dw * (wm(ibld(jsp)) - wm(ibld(jsm2)))

ELSE

ism2 = is1 - 2

IF (ism2 < 1) THEN ism2 = ism2 + nblade

isp = is1 + 1

IF (isp > nblade) THEN isp = 1

dd = dw * (wm(ibld(isp)) - wm(ibld(ism2)))

END IF

ELSE

ism = is1 - 1

IF (ism = 0) THEN ism = nblade

isp = is1 + 1

IF (isp > nblade) THEN isp = 1

jsm = js - 1

IF (jsm = 0) THEN jsm = nblade

jsp = js + 1

IF (jsp > nblade) THEN jsp = 1

dd = dw * (wm(ibld(isp)) + wm(ibld(ism)) - wm(ibld(jsp)) - wm(ibld(jsm))) - .000001#

END IF

dmb = dx * dx + dy * dy

'SEE WHETHER WE WANT TO SWAP

'PASS 1 - DON'T SWAP IT PITCH ERROR WOULD GET BIGGER

IF (ipass = 1) THEN

IF (dmb < minset OR dmb > maxset) THEN GOTO inner

 

'PASS 2 - DON'T SWAP IF UNBALANCE GETS BIGGER OR BOTH PAKCKETS GO OUT

'OF TOLERANCE AND EITHER THEY WERE IN BEFORE OR PITCH ERROR

'WOULD INCREASE

ELSEIF (ipass = 2) THEN

IF (ang < 239 OR ang > 241) THEN GOTO inner

'PASS 3 - DONT'T SWAP IF DISTRIBUTION FUNCTION GETS SMALLER OR

'UNBALANCE GOES OUT OF TOLERANCE OR BOTH PACKETS GO OUT OF

'TOLERANCE AND EITHER THEY WERE IN BEFORE OR PITCH ERROR

'WOULD INCREASE

ELSE

IF (dd <= 0# OR dmb > tol) THEN GOTO inner

END IF

 

'DO SWAP

dfun = dfun + dd

ubnet = dmb

xm = dx

ym = dy

SWAP istn(ib), istn(jb)

SWAP ibld(is1), ibld(js)

 

'SEE WHETHER SWAP HAS BROUGHT CURRENT PASS WITHIN TOLERANCE

 

IF (ipass = 1) THEN

IF (ubnet > minset ^ 2 AND ubnet < maxset) THEN

ipass = 2

GOTO result

END IF

 

ELSEIF (ipass = 2) THEN

IF (ang > 239 AND ang < 241) THEN

ipass = 3

GOTO result

END IF

ELSE

IF (dfun >= dist) THEN GOTO resultout

END IF

IF (l > l1) THEN GOTO OUTER

'END OF INNER LOOP

inner:

NEXT k

'END OF OUTER LOOP

NEXT l

'IF WE ARRIVE HERE SOMETHING MUST BE OUT OF TOLERANCE

'GO ON TO NEXT PASS

IF (ipass < 3) THEN

ipass = ipass + 1

GOTO result

END IF

 

'OUTPUT RESULTS

'40 BLADES ON EACH PAGE EXCEPT 1ST

resultout:

IF (wfile <> "X") THEN

kount = 10

ELSE

kount = 0

END IF

nbeff = nblade + kount

npag = INT((nbeff + 39) / 40)

ipag = 1

kstart = 1

tol = SQR(tol)

ubnet = SQR(ubnet)

IF (worm = "M") THEN

IF (ABS(swm) < .000001#) THEN

tow = 0#

ELSE

tow = ubnet / swm

END IF

ELSE

tow = ubnet

END IF

IF (ABS(disb - diss) < .000001#) THEN

drat = 1#

ELSE

drat = (dfun - diss) / (disb - diss)

END IF

IF (iswap = 0) THEN

lline = "BLADES NOT SORTED FROM ORIGINAL ORDER"

ELSE

lline = "BALANCING ON"

 

IF (wfile <lt;> "X") THEN

IF (worm = "W") THEN

mline = " WEIGHTS "

ELSE

mline = " MOMENTS"

END IF

END IF

END IF

'PRINT O/P

FOR i = 1 TO nblade

kount = kount + 1

'PRINT HEADINGS BEFORE 1ST BLADE THEN AT START OF EACH NEW PAGE

'kstart FORCES HEADING BEFORE 1st BLADE. KOUNT DOESN'T ALWAYS START

'FROM 0 TO ALLOW FOR EXTRA THINGS PRINTED ON 1st PAGE.

IF (kount >= 40 OR kstart = 1) THEN

IF (kstart <> 1) THEN kount = 0

LPRINT " 'KIM KAY YOUN' Moment Balancing Program-Version "; verd

LPRINT

LPRINT btitle; "("; wfile; ")"; SPC(30); "page"; ipag; " of "; npag

LPRINT undrln

LPRINT

LPRINT "Lightest blade wt. = "; smlwt; " KG"; " no."; isml; "("; smlnam; ")"

LPRINT "Heaviest blade wt. = "; bigwt; " KG"; " no."; ibig; "("; bignam; ")"

LPRINT "Average weight = ";:LPRINT USING "##.###"; avwt; : LPRINT " KG";

LPRINT SPC(3); "Heaviest-lightest = "; : LPRINT USING "##.###"; hml; : LPRINT " KG"

LPRINT "Average moment = "; : LPRINT USING "##.####"; avmom; : LPRINT " KG-M";

LPRINT " Avg jig to pfm gap = "; avjf

kstart = 0

LPRINT "Blade Dwg. No.";dwgno; SPC(15);"Calculated "; DATE$; " "; TIME$

IF (worm = "M") THEN

IF (optw = "N") THEN

IF (ipag = 1) THEN

LPRINT "Final balance "; : LPRINT USING "##.####^^^^"; ubnet; : LPRINT " KG-M ";

LPRINT " Direction "; : LPRINT USING "###.##"; ang; : LPRINT " Degree"

LPRINT "Unbalanced wt. "; : LPRINT USING "####.##"; tow * 1000;

LPRINT " gr at "; : LPRINT USING "#.###"; swm; : LPRINT " M. radius"

END IF

ELSE

IF (ipag = 1) THEN

LPRINT "Final balance "; : LPRINT USING "##.####^^^^"; ubnet; : LPRINT " KG-M";

LPRINT "Direction"; : LPRINT USING "###.##"; ang; : LPRINT "Degree"

LPRINT "Unbalanced wt. "; : LPRINT USING "####.##"; tow * 1000;

LPRINT " gr at "; : LPRINT USING "#.###"; swm; : LPRINT " M. radius"

LPRINT "Tolerance "; wub * 1000; " gr. at "; : LPRINT USING "#.###"; swm;

LPRINT " M radius"

END IF

END IF

ELSE

IF (ipag = 1) THEN

LPRINT "Final balance "; : LPRINT USING "##.####^^^^"; ubnet; : LPRINT " KG-M";

LPRINT "Direction"; : LPRINT USING "###.##"; ang; : LPRINT " DEGREE"

LPRINT "Tolerance "; wub * 1000; " gr"

END IF

END IF

IF (optw = "N") THEN

IF (ipag = 1) THEN

LPRINT "Distribution Achieved "; : LPRINT USING "#.####"; drat

END IF

ELSE

IF (ipag = 1) THEN

LPRINT "Distribution Achieved "; : LPRINT USING "#.####"; drat;

LPRINT " Tolerance "; distol

END IF

END IF

IF (ipag = 1) THEN

IF (tow > wub) THEN

LPRINT "WARNING - FINAL BALANCE NOT IN TOLERANCE"

END IF

IF (drat < distol) THEN

LPRINT "WARNING - FINAL DISTRIBUTION NOT IN TOLERANCE"

END IF

END IF

LPRINT lline + mline

LPRINT

LPRINT "DISC";SPC(9);"BLADE"; SPC(8); "WTTOTAL"; SPC(3); "SCHMOM";

LPRINT SPC(4); "JIGPFM"; SPC(4); "MOMENT"; SPC(7); "CG"

LPRINT "STN NO. IDENT."; SPC(8); "(KG)"; SPC(4); "(KG-M)";

LPRINT SPC(5); "(MM)"; SPC(4); "(KG-M)"; SPC(6); "(M)"

ipag = ipag + 1

END IF

ib = ibld(i)

c1 = " "

IF (istn(ib) <= 0) THEN c1 = "F"

'PRINT SWAP RESULT

LPRINT USING "###"; i; : LPRINT SPC(3); : LPRINT USING "###"; ib;

LPRINT c1; SPC(1); bname(ib); SPC(4); : LPRINT USING "##.###"; wt(ib);

LPRINT SPC(3); : LPRINT USING "##.####"; sm(ib);

LPRINT SPC(3); : LPRINT USING "###.##"; cjf(ib); : LPRINT SPC(3);

LPRINT USING "##.#####"; tm(ib); : LPRINT SPC(3);

LPRINT USING "##.####"; cg(ib)

IF kount = 39 THEN LPRINT CHR$(12)

NEXT i

END

 

'BLADE WEIGHT & MOMENT DATA FOR LP2 FRONT(RHS) 1993.6

 

1 DATA 1 K1001 ,61.274,54.8504,174.51

2 DATA 2 K1002 ,61.120,54.7396,174.67

3 DATA 3 K1003 ,59.366,52.6220,173.56

4 DATA 4 K1004 ,60.811,54.3820,174.14

5 DATA 5 K1005 ,60.263,53.5118,174.30

6 DATA 6 K1006 ,61.317,55.0308,173.85

7 DATA 7 K1007 ,60.872,54.5790,173.63

8 DATA 8 K1008 ,61.256,54.8406,174.34

9 DATA 9 K1009 ,61.171,54.9554,174.24

10 DATA 10 K1010 ,59.357,52.5076,173.52

11 DATA 11 K1011 ,60.623,54.0104,173.81

12 DATA 12 K1012 ,60.721,54.1592,174.04

13 DATA 13 K1013 ,60.955,54.6050,173.89

14 DATA 14 K1014 ,60.014,53.2346,173.69

15 DATA 15 K1015 ,61.211,54.7332,173.77

16 DATA 16 K1016 ,60.557,54.1442,173.09

17 DATA 17 K1017 ,60.875,54.4464,173.63

18 DATA 18 K1018 ,61.528,54.8014,174.16

19 DATA 19 K1019 ,60.771,54.3074,174.03

20 DATA 20 K1020 ,60.165,53.6560,174.24

21 DATA 21 K1021 ,61.325,54.7196,174.02

22 DATA 22 K1022 ,60.953,54.7078,174.24

23 DATA 23 K1023 ,61.356,54.8686,173.35

24 DATA 24 K1024 ,60.399,53.5984,174.39

25 DATA 25 K1025 ,60.193,53.4414,174.74

26 DATA 26 K1026 ,61.775,55.6876,173.83

27 DATA 27 K1027 ,61.476,55.0588,174.14

28 DATA 28 K1028 ,61.238,54.8798,173.96

29 DATA 29 K1029 ,60.488,53.8126,174.13

30 DATA 30 K1030 ,61.237,54.7234,173.83

31 DATA 31 K1031 ,60.760,54.1364,174.84

32 DATA 32 K1032 ,59.299,52.6734,173.02

33 DATA 33 K1033 ,60.830,54.3126,174.47

34 DATA 34 K1034 ,61.328,54.9674,173.80

35 DATA 35 K1035 ,61.740,55.3734,173.89

36 DATA 36 K1036 ,61.096,54.6624,173.65

37 DATA 37 K1037 ,61.690,55.0654,174.42

38 DATA 38 K1038 ,61.245,54.8930,174.00

39 DATA 39 K1039 ,61.751,55.4016,174.04

40 DATA 40 K1040 ,61.383,55.0864,174.50

41 DATA 41 K1041 ,60.244,53.2910,174.54

42 DATA 42 K1042 ,60.665,53.9206,174.84

43 DATA 43 K1043 ,59.705,52.9246,174.41

44 DATA 44 K1044 ,61.212,54.6964,174.66

45 DATA 45 K1045 ,61.082,54.6732,173.79

46 DATA 46 K1046 ,60.376,53.8116,173.89

47 DATA 47 K1047 ,60.376,53.8630,173.56

48 DATA 48 K1048 ,61.681,55.5014,173.93

49 DATA 49 K1049 ,60.897,54.6198,173.52

50 DATA 50 K1050 ,62.187,55.8644,174.48

51 DATA 51 K1051 ,58.996,52.0830,174.08

52 DATA 52 K1052 ,61.257,54.8038,174.18

53 DATA 53 K1053 ,60.866,54.5744,173.75

54 DATA 54 K1054 ,60.796,54.3458,174.25

55 DATA 55 K1055 ,61.632,55.1416,173.73

56 DATA 56 K1056 ,62.024,55.7910,173.30

57 DATA 57 K1057 ,60.383,53.8678,174.08

58 DATA 58 K1058 ,61.456,55.0068,174.49

59 DATA 59 K1059 ,60.665,54.3464,173.19

60 DATA 60 K1060 ,60.817,54.4334,173.99

61 DATA 61 K1061 ,61.430,54.8986,174.21

62 DATA 62 K1062 ,60.745,54.3828,174.23

63 DATA 63 K1063 ,61.247,54.7344,174.02

64 DATA 64 K1064 ,60.641,54.1554,174.39

 

 
TRAC Mark INCOSYS